# denpa-radio liquidsoap script
# adding a station: copy a station block, rename, restart liquidsoap.

settings.log.stdout.set(true)
settings.log.level.set(3)

source_pw = environment.get(default="", "SOURCE_PW")

def emit_now_playing(station, m) =
  filename = m["filename"]
  if filename != "" then
    payload = json()
    payload.add("station", station)
    payload.add("artist", m["artist"])
    payload.add("title", m["title"])
    payload.add("album", m["album"])
    payload.add("filename", filename)
    payload.add("started_at", string(int_of_float(time())))
    file.write(data=payload.stringify(), atomic=true, temp_dir="/now-playing", "/now-playing/#{station}.json")
  end
end

# === station: minecraft ===
minecraft = playlist(
  reload_mode="watch",
  mode="randomize",
  "/library/minecraft/tracks"
)
minecraft.on_track(fun (m) -> emit_now_playing("minecraft", m))
minecraft = crossfade(minecraft)
minecraft = mksafe(minecraft)

output.icecast(
  %mp3(bitrate=192, stereo=true),
  host="icecast", port=8000, password=source_pw,
  mount="/minecraft.mp3",
  name="Denpa — Minecraft",
  description="Minecraft soundtracks",
  genre="game-ost",
  url="https://denpa.femboy.page",
  minecraft
)

output.icecast(
  %opus(bitrate=96, vbr="constrained", samplerate=48000, channels=2),
  host="icecast", port=8000, password=source_pw,
  mount="/minecraft.opus",
  name="Denpa — Minecraft",
  description="Minecraft soundtracks",
  genre="game-ost",
  url="https://denpa.femboy.page",
  minecraft
)